[애플스크립트] 키노트 슬라이드 이미지 캡쳐

애플스크립트를 사용하면 더 간편하게 슬라이드 이미지를 저장할 수 있습니다.

 

키노트 페이지를 저장하려면 메뉴 → 파일 → 다음으로 저장하기 → 이미지... 를 클릭하고 어떤 형식으로 저장할지 선택→ 저장할 위치 설정 까지 마친 후에야 슬라이드 캡쳐 이미지를 얻을 수 있습니다. 한두번이면 괜찮지만 여러번 반복하다보면 아주 귀찮고 불편합니다. 애플 스크립트를 사용하면 이 과정을 한방에 할 수 있습니다.

 

모든 슬라이드 이미지 캡쳐

tell application "Keynote"
	activate
	-- "~/Downloads/Keynote Capture" 폴더에 저장
	set descPath to (path to downloads folder as string) & "Keynote Capture"
	
	-- 모든 슬라이드 활성화
	set skipped of front document's slides 1 thru -1 to false
	
	-- 슬라이드 이미지 저장
	-- image format: JPEG, PNG, TIFF 포맷을 설정가능
	-- compression factor: 이미지 압축율 최대값 1, 최소값 0
	export front document as slide images to file descPath with properties {image format:JPEG, compression factor:1.0}
end tell

 

현재 슬라이드 이미지 캡쳐

tell application "Keynote"
	activate
	-- "~/Downloads/Keynote Capture" 폴더에 저장
	set descPath to (path to downloads folder as string) & "Keynote Capture"
	
	-- 현재 슬라이드 변호
	set currentSlide to front document's slide number of current slide
	-- 모든 슬라이드 건너뛰기
	set skipped of front document's slides 1 thru -1 to true
	-- 현재 슬라이드만 활성화
	set skipped of front document's slide currentSlide to false
	
	-- 슬라이드 이미지 저장
	-- skipped slides: false, 슬라이드 건너뛰기 설정된 슬라이드는 이미지로 저장안함
	export front document as slide images to file descPath with properties {image format:JPEG, skipped slides:false, compression factor:1.0}
	delay 1
	
	-- 모든 슬라이드 활성화
	set skipped of front document's slides 1 thru -1 to false
end tell

 

 

 

 

---

 

참고

🔗 https://iworkautomation.com/keynote/document-export.html